diff --git a/package.json b/package.json
index 5a99c86e8..95f0d58c8 100644
--- a/package.json
+++ b/package.json
@@ -1,59 +1,60 @@
 {
   "private": true,
   "license": "BSD-3-Clause",
   "workspaces": [
     "lib",
     "web",
     "native",
     "keyserver",
     "landing",
     "desktop",
     "keyserver/addons/rust-node-addon",
     "native/expo-modules/comm-expo-package",
     "services/electron-update-server",
     "web/opaque-ke-wasm"
   ],
   "scripts": {
     "clean": "yarn workspace lib clean && yarn workspace web clean && yarn workspace native clean && yarn workspace keyserver clean && yarn workspace landing clean && yarn workspace desktop clean && yarn workspace rust-node-addon clean && yarn workspace electron-update-server clean && rm -rf node_modules/",
     "cleaninstall": "(killall flow || pkill flow || true) && yarn clean && yarn",
     "ci-cleaninstall": "yarn cleaninstall --frozen-lockfile --skip-optional --network-timeout 180000",
     "eslint:all": "eslint --report-unused-disable-directives .",
     "eslint:fix": "eslint --fix --report-unused-disable-directives .",
     "clang-format-all": "eval `node scripts/get-clang-paths-cli.js` | xargs clang-format -i",
     "rust-pre-commit": "./scripts/rust_pre_commit.sh",
     "terraform-pre-commit": "./scripts/terraform_pre_commit.sh",
     "prepare": "husky install",
     "arcpatch": "git pull --all --tags && arc patch",
     "postinstall": "bash ./postinstall.sh",
     "flow:all": "yarn workspace lib flow && yarn workspace web flow && yarn workspace landing flow && yarn workspace native flow && yarn workspace keyserver flow && yarn workspace desktop flow && yarn workspace electron-update-server flow",
-    "jest:all": "yarn workspace lib test && yarn workspace keyserver test && yarn workspace web test && yarn workspace native test"
+    "jest:all": "yarn workspace lib test && yarn workspace keyserver test && yarn workspace web test && yarn workspace native test",
+    "docker-build-push:identity": "./scripts/docker-build-push-identity.sh"
   },
   "devDependencies": {
     "@babel/eslint-parser": "^7.23.3",
     "@stylistic/eslint-plugin-js": "^1.5.3",
     "clang-format": "^1.8.0",
     "core-js": "^3.6.5",
     "eslint": "^8.56.0",
     "eslint-config-prettier": "^9.1.0",
     "eslint-plugin-flowtype": "^8.0.3",
     "eslint-plugin-import": "^2.29.1",
     "eslint-plugin-jest": "^27.6.1",
     "eslint-plugin-monorepo": "^0.3.2",
     "eslint-plugin-prettier": "^5.1.2",
     "eslint-plugin-react": "^7.33.2",
     "eslint-plugin-react-hooks": "^4.6.0",
     "eslint-plugin-react-native": "^4.1.0",
     "eslint-plugin-unicorn": "^51.0.1",
     "find-up": "^5.0.0",
     "flow-mono-cli": "^1.5.0",
     "gaxios": "^4.3.2",
     "husky": "^7.0.0",
     "lint-staged": "^12.1.4",
     "patch-package": "^6.4.7",
     "postinstall-postinstall": "^2.0.0",
     "prettier": "^3.1.1"
   },
   "resolutions": {
     "react-native-flipper": "https://registry.yarnpkg.com/@favware/skip-dependency/-/skip-dependency-1.1.1.tgz"
   }
 }
diff --git a/scripts/docker-build-push-identity.sh b/scripts/docker-build-push-identity.sh
new file mode 100755
index 000000000..572aaa216
--- /dev/null
+++ b/scripts/docker-build-push-identity.sh
@@ -0,0 +1,5 @@
+#!/bin/bash
+
+TAG=$1
+
+docker build --platform linux/amd64 -f services/identity/Dockerfile -t commapp/identity-server:"$TAG" . && docker push commapp/identity-server:"$TAG"
diff --git a/services/terraform/remote/service_identity.tf b/services/terraform/remote/service_identity.tf
index e2950746a..df0c588c0 100644
--- a/services/terraform/remote/service_identity.tf
+++ b/services/terraform/remote/service_identity.tf
@@ -1,300 +1,300 @@
 locals {
-  identity_service_image_tag      = local.is_staging ? "farcaster" : "0.12"
+  identity_service_image_tag      = local.is_staging ? "0.13-staging" : "0.13"
   identity_service_server_image   = "commapp/identity-server:${local.identity_service_image_tag}"
   identity_service_container_name = "identity-server"
 
   # Port that the container is listening on
   identity_service_container_grpc_port = 50054
   identity_sc_port_name                = "identity-service-ecs-grpc"
   identity_sc_dns_name                 = "identity-service"
 
   # Port that Websocket server listens on
   identity_service_container_ws_port = 51004
   identity_sc_ws_port_name           = "identity-service-ecs-ws"
 
   # URL accessible by other services in the same Service Connect namespace
   # This renders to e.g. 'http://identity-service:50054'
   identity_local_url = "http://${local.identity_sc_dns_name}:${local.identity_service_container_grpc_port}"
 
   # Port that is exposed to the public SSL endpoint (appended to domain name)
   identity_service_grpc_public_port = 50054
   identity_service_domain_name      = "identity.${local.root_domain}"
 
   opaque_server_setup_secret_name = "identity/ServerSetup"
   staging_allow_origin_list       = <<EOT
     http://localhost:3000,
     http://localhost:3001,
     http://localhost:3002,
     http://localhost:3003,
     http://localhost:3004,
     http://localhost:3005,
     http://localhost:3006,
     http://localhost:3007,
     http://localhost:3008,
     http://localhost:3009
   EOT
   production_allow_origin_list    = "https://web.comm.app"
 }
 
 data "aws_secretsmanager_secret" "identity_server_setup" {
   name = local.opaque_server_setup_secret_name
 }
 
 resource "aws_ecs_task_definition" "identity_service" {
   family = "identity-service-task-def"
   container_definitions = jsonencode([
     {
       name      = local.identity_service_container_name
       image     = local.identity_service_server_image
       essential = true
       portMappings = [
         {
           name          = local.identity_sc_port_name
           containerPort = local.identity_service_container_grpc_port
           protocol      = "tcp"
           appProtocol   = "grpc"
         },
         {
           name          = local.identity_sc_ws_port_name
           containerPort = local.identity_service_container_ws_port
           protocol      = "tcp"
           appProtocol   = "http"
         }
       ]
       environment = [
         {
           name  = "RUST_LOG"
           value = "info"
         },
         {
           name  = "KEYSERVER_PUBLIC_KEY"
           value = nonsensitive(local.secrets["keyserverPublicKey"])
         },
         {
           name  = "TUNNELBROKER_GRPC_ENDPOINT"
           value = local.tunnelbroker_local_grpc_url
         },
         {
           name  = "OPENSEARCH_ENDPOINT"
           value = module.shared.opensearch_domain_identity.endpoint
         },
         {
           name  = "ALLOW_ORIGIN_LIST"
           value = local.is_staging ? local.staging_allow_origin_list : local.production_allow_origin_list
         }
       ]
       secrets = [
         {
           # This is exposed as an environment variable in the container
           name      = "OPAQUE_SERVER_SETUP"
           valueFrom = data.aws_secretsmanager_secret.identity_server_setup.arn
         }
       ]
       logConfiguration = {
         "logDriver" = "awslogs"
         "options" = {
           "awslogs-create-group"  = "true"
           "awslogs-group"         = "/ecs/identity-service-task-def"
           "awslogs-region"        = "us-east-2"
           "awslogs-stream-prefix" = "ecs"
         }
       }
       linuxParameters = {
         initProcessEnabled = true
       }
     }
   ])
   task_role_arn            = aws_iam_role.services_ddb_full_access.arn
   execution_role_arn       = aws_iam_role.ecs_task_execution.arn
   network_mode             = "bridge"
   cpu                      = "512"
   memory                   = "512"
   requires_compatibilities = ["EC2"]
 
   # Set this to true if you want to keep old revisions
   # when this definition is changed
   skip_destroy = false
 }
 
 resource "aws_ecs_service" "identity_service" {
   name        = "identity-service"
   cluster     = aws_ecs_cluster.comm_services.id
   launch_type = "EC2"
 
   task_definition      = aws_ecs_task_definition.identity_service.arn
   force_new_deployment = true
 
   desired_count = 2
 
   # Expose Identity service to other services in the cluster
   service_connect_configuration {
     enabled = true
     service {
       discovery_name = local.identity_sc_dns_name
       port_name      = local.identity_sc_port_name
       client_alias {
         port     = local.identity_service_container_grpc_port
         dns_name = local.identity_sc_dns_name
       }
     }
   }
 
   load_balancer {
     target_group_arn = aws_lb_target_group.identity_service_ws.arn
     container_name   = local.identity_service_container_name
     container_port   = local.identity_service_container_ws_port
   }
 
   load_balancer {
     target_group_arn = aws_lb_target_group.identity_service_grpc.arn
     container_name   = local.identity_service_container_name
     container_port   = local.identity_service_container_grpc_port
   }
 
   deployment_circuit_breaker {
     enable   = true
     rollback = true
   }
 
   enable_execute_command  = true
   enable_ecs_managed_tags = true
 }
 
 # Security group to configure access to the service
 resource "aws_security_group" "identity_service" {
   name   = "identity-service-ecs-sg"
   vpc_id = aws_vpc.default.id
 
   ingress {
     from_port   = local.identity_service_container_grpc_port
     to_port     = local.identity_service_container_grpc_port
     protocol    = "tcp"
     cidr_blocks = ["0.0.0.0/0"]
     description = "gRPC port"
   }
 
   ingress {
     from_port   = local.identity_service_container_ws_port
     to_port     = local.identity_service_container_ws_port
     protocol    = "tcp"
     cidr_blocks = ["0.0.0.0/0"]
     description = "Websocket port"
   }
 
   # Allow all outbound traffic
   egress {
     from_port   = 0
     to_port     = 0
     protocol    = "-1"
     cidr_blocks = ["0.0.0.0/0"]
   }
 
   lifecycle {
     create_before_destroy = true
   }
 }
 
 resource "aws_lb_target_group" "identity_service_grpc" {
   name             = "identity-service-ecs-grpc-tg"
   port             = local.identity_service_container_grpc_port
   protocol         = "HTTP"
   protocol_version = "HTTP2"
   vpc_id           = aws_vpc.default.id
 
   # The "bridge" network mode requires target type set to instance
   target_type = "instance"
 
   stickiness {
     type            = "lb_cookie"
     cookie_duration = 10 # Duration in seconds
     enabled         = true
   }
 
   health_check {
     enabled             = true
     healthy_threshold   = 2
     unhealthy_threshold = 3
   }
 }
 
 resource "aws_lb_target_group" "identity_service_ws" {
   name             = "identity-service-ecs-ws-tg"
   port             = local.identity_service_container_ws_port
   protocol         = "HTTP"
   protocol_version = "HTTP1"
   vpc_id           = aws_vpc.default.id
   target_type      = "instance"
 
   health_check {
     enabled             = true
     healthy_threshold   = 2
     unhealthy_threshold = 3
 
     protocol = "HTTP"
     path     = "/health"
     matcher  = "200"
 
   }
 }
 
 # Load Balancer
 resource "aws_lb" "identity_service" {
   load_balancer_type = "application"
   name               = "identity-service-lb"
   internal           = false
   subnets = [
     aws_subnet.public_a.id,
     aws_subnet.public_b.id,
     aws_subnet.public_c.id,
   ]
 }
 
 resource "aws_lb_listener" "identity_service_ws" {
   load_balancer_arn = aws_lb.identity_service.arn
   port              = local.identity_service_container_ws_port
   protocol          = "HTTPS"
   ssl_policy        = "ELBSecurityPolicy-2016-08"
   certificate_arn   = data.aws_acm_certificate.identity_service.arn
 
   default_action {
     type             = "forward"
     target_group_arn = aws_lb_target_group.identity_service_ws.arn
   }
 
   lifecycle {
     ignore_changes       = [default_action[0].forward[0].stickiness[0].duration]
     replace_triggered_by = [aws_lb_target_group.identity_service_ws]
   }
 }
 
 resource "aws_lb_listener" "identity_service_grpc" {
   load_balancer_arn = aws_lb.identity_service.arn
   port              = local.identity_service_grpc_public_port
   protocol          = "HTTPS"
   ssl_policy        = "ELBSecurityPolicy-TLS13-1-2-2021-06"
   certificate_arn   = data.aws_acm_certificate.identity_service.arn
 
   default_action {
     type             = "forward"
     target_group_arn = aws_lb_target_group.identity_service_grpc.arn
   }
 
   lifecycle {
     # Required only for existing resources to avoid plan difference
     ignore_changes = [default_action[0].forward[0].stickiness[0].duration]
 
     # Target group cannot be destroyed if it is used
     replace_triggered_by = [aws_lb_target_group.identity_service_grpc]
   }
 }
 
 # SSL Certificate
 data "aws_acm_certificate" "identity_service" {
   domain   = local.identity_service_domain_name
   statuses = ["ISSUED"]
 }
 
 # Required for Route53 DNS record
 output "identity_service_load_balancer_dns_name" {
   value = aws_lb.identity_service.dns_name
 }