diff --git a/services/terraform/self-host/aws_db.tf b/services/terraform/self-host/aws_db.tf
index 96ecb3df2..1699fa7dc 100644
--- a/services/terraform/self-host/aws_db.tf
+++ b/services/terraform/self-host/aws_db.tf
@@ -1,99 +1,113 @@
 # MariaDB Security Group
 resource "aws_security_group" "keyserver_mariadb_security_group" {
   name        = "keyserver-mariadb-sg"
   description = "Allow inbound traffic on port 3307 and all outbound traffic"
   vpc_id      = local.vpc_id
 
   # Inbound rules
   ingress {
     from_port       = 3307
     to_port         = 3307
     protocol        = "tcp"
     security_groups = [aws_security_group.keyserver_service.id]
   }
 
   ingress {
     from_port   = 3307
     to_port     = 3307
     protocol    = "tcp"
     cidr_blocks = ["${var.allowed_ip}/32"]
   }
 
   # Outbound rules
   egress {
     from_port   = 0
     to_port     = 0
     protocol    = "-1"
     cidr_blocks = ["0.0.0.0/0"]
   }
 }
 
 # MariaDB RDS Instance
 resource "aws_db_instance" "mariadb" {
   allocated_storage      = 100
   max_allocated_storage  = 3000
   storage_type           = "gp3"
   db_name                = "mariadb"
   identifier             = "mariadb-instance"
   engine                 = "mariadb"
   engine_version         = "10.11"
   instance_class         = "db.m6g.large"
   db_subnet_group_name   = aws_db_subnet_group.public_db_subnet_group.name
   vpc_security_group_ids = [aws_security_group.keyserver_mariadb_security_group.id]
   username               = var.mariadb_username
   password               = var.mariadb_password
   parameter_group_name   = aws_db_parameter_group.mariadb_parameter_group.name
   storage_encrypted      = true
   publicly_accessible    = true
   port                   = 3307
   skip_final_snapshot    = true
 }
 
 # MariaDB Parameter Group
 resource "aws_db_parameter_group" "mariadb_parameter_group" {
   name   = "mariadb-parameter-group"
   family = "mariadb10.11"
 
   parameter {
     apply_method = "pending-reboot"
     name         = "performance_schema"
     value        = "1"
   }
 
   parameter {
     apply_method = "immediate"
     name         = "max_allowed_packet"
     # 256 MiB: (1024 * 1024 * 256)
     value = "268435456"
   }
 
   parameter {
     apply_method = "immediate"
     name         = "local_infile"
     value        = "0"
   }
 
   parameter {
     apply_method = "immediate"
     name         = "sql_mode"
     value        = "STRICT_ALL_TABLES"
   }
 
   parameter {
     apply_method = "pending-reboot"
     name         = "innodb_buffer_pool_size"
     value        = "{DBInstanceClassMemory*3/4}"
   }
 
   parameter {
     apply_method = "pending-reboot"
     name         = "innodb_ft_min_token_size"
     value        = "1"
   }
 
   parameter {
     apply_method = "immediate"
     name         = "innodb_ft_enable_stopword"
     value        = "0"
   }
 }
+
+resource "null_resource" "create_comm_database" {
+  depends_on = [aws_db_instance.mariadb, aws_security_group.keyserver_mariadb_security_group]
+
+  provisioner "local-exec" {
+    command = <<EOT
+    mysql --user=${var.mariadb_username} \
+          --port=3307 \
+          --host=${aws_db_instance.mariadb.address} \
+          --execute="CREATE DATABASE IF NOT EXISTS comm;" \
+          --password=${var.mariadb_password}
+    EOT
+  }
+}
diff --git a/services/terraform/self-host/keyserver_primary.tf b/services/terraform/self-host/keyserver_primary.tf
index bbc2dce0a..3862317f8 100644
--- a/services/terraform/self-host/keyserver_primary.tf
+++ b/services/terraform/self-host/keyserver_primary.tf
@@ -1,179 +1,181 @@
 locals {
   keyserver_service_image_tag      = "0.1"
   keyserver_service_server_image   = "commapp/keyserver:${local.keyserver_service_image_tag}"
   keyserver_service_container_name = "keyserver-primary"
 }
 
 resource "aws_cloudwatch_log_group" "ecs_log_group" {
   name              = "/ecs/keyserver-primary-task-def"
   retention_in_days = 7
 }
 
 output "mariadb_address" {
   value = aws_db_instance.mariadb.address
 }
 
 resource "aws_ecs_task_definition" "keyserver_service" {
   network_mode             = "awsvpc"
   family                   = "keyserver-primary-task-def"
   requires_compatibilities = ["FARGATE"]
   task_role_arn            = aws_iam_role.ecs_task_role.arn
   execution_role_arn       = aws_iam_role.ecs_task_execution.arn
   cpu                      = "2048"
   memory                   = "4096"
 
   ephemeral_storage {
     size_in_gib = 40
   }
 
   container_definitions = jsonencode([
     {
       name      = local.keyserver_service_container_name
       image     = local.keyserver_service_server_image
       essential = true
       portMappings = [
         {
           name          = "keyserver-port"
           containerPort = 3000
           hostPort      = 3000,
           protocol      = "tcp"
         },
 
       ]
       environment = [
         {
           name  = "COMM_LISTEN_ADDR"
           value = "0.0.0.0"
         },
         {
           name  = "COMM_DATABASE_HOST"
           value = "${aws_db_instance.mariadb.address}"
         },
         {
           name  = "COMM_DATABASE_DATABASE"
           value = "comm"
         },
         {
           name  = "COMM_DATABASE_PORT"
           value = "3307"
         },
         {
           name  = "COMM_DATABASE_USER"
           value = "${var.mariadb_username}"
         },
         {
           name  = "COMM_DATABASE_PASSWORD"
           value = "${var.mariadb_password}"
         },
         {
           name  = "COMM_JSONCONFIG_secrets_user_credentials"
           value = jsonencode(var.keyserver_user_credentials)
         },
         {
           name = "COMM_JSONCONFIG_facts_webapp_cors"
           value = jsonencode({
             "domain" : "https://web.comm.app"
           })
         },
         {
           name = "COMM_JSONCONFIG_facts_keyserver_url"
           value = jsonencode({
             "baseDomain" : "https://${var.domain_name}",
             "basePath" : "/",
             "baseRoutePath" : "/",
             "https" : false,
             "proxy" : "none"
           })
         },
         {
           name = "COMM_JSONCONFIG_secrets_identity_service_config",
           value = jsonencode({
             "identitySocketAddr" : "${var.identity_socket_address}"
           })
         },
       ]
       logConfiguration = {
         "logDriver" = "awslogs"
         "options" = {
           "awslogs-create-group"  = "true"
           "awslogs-group"         = aws_cloudwatch_log_group.ecs_log_group.name
           "awslogs-stream-prefix" = "ecs"
           "awslogs-region"        = "${var.region}"
         }
       }
       linuxParameters = {
         initProcessEnabled = true
       }
     }
   ])
 
   runtime_platform {
     cpu_architecture        = "ARM64"
     operating_system_family = "LINUX"
   }
 
   skip_destroy = false
 }
 
 resource "aws_ecs_service" "keyserver_primary_service" {
+  depends_on = [null_resource.create_comm_database]
+
   name                    = "keyserver-primary-service"
   cluster                 = aws_ecs_cluster.keyserver_cluster.id
   task_definition         = aws_ecs_task_definition.keyserver_service.arn
   launch_type             = "FARGATE"
   enable_execute_command  = true
   enable_ecs_managed_tags = true
   force_new_deployment    = true
   desired_count           = 1
 
   network_configuration {
     subnets          = local.vpc_subnets
     security_groups  = [aws_security_group.keyserver_service.id]
     assign_public_ip = true
   }
 
   load_balancer {
     target_group_arn = aws_lb_target_group.keyserver_service.arn
     container_name   = local.keyserver_service_container_name
     container_port   = 3000
   }
 
   deployment_circuit_breaker {
     enable   = true
     rollback = true
   }
 }
 
 resource "aws_security_group" "keyserver_service" {
   name   = "keyserver-service-ecs-sg"
   vpc_id = local.vpc_id
 
   # Allow all inbound traffic  on port 3000
   ingress {
     from_port   = 3000
     to_port     = 3000
     protocol    = "tcp"
     cidr_blocks = ["0.0.0.0/0"]
   }
 
   ingress {
     description      = "Allow inbound traffic from any IPv6 address"
     from_port        = 3000
     to_port          = 3000
     protocol         = "tcp"
     ipv6_cidr_blocks = ["::/0"]
   }
 
   # Allow all outbound traffic
   egress {
     from_port   = 0
     to_port     = 0
     protocol    = "-1"
     cidr_blocks = ["0.0.0.0/0"]
   }
 
   lifecycle {
     create_before_destroy = true
   }
 }